'From Croquet1.0beta of 11 April 2006 [latest update: #1] on 6 August 2008 at 12:53:03 pm'!

!Parser methodsFor: 'public access' stamp: 'eem 6/19/2008 09:38'!
encoder
	encoder isNil ifTrue:
		[encoder := EncoderForV3PlusClosures new].
	^encoder! !

"Postscript:
Recompile the system and do some minimal clean-ups"
"Recompile the system except the one method we can't yet deal with in GeniePlugin (1 too many literals)"
| classes compilationErrors |
compilationErrors := Set new.
classes := Smalltalk forgetDoIts allClasses reject: [:c| c name == #GeniePlugin].
'Recompiling The System'
	displayProgressAt: Sensor cursorPoint
	from: 0 to: classes size
	during:
		[:bar |
		classes withIndexDo:
			[:c :i|
			bar value: i.
			{ c. c class } do:
				[:b|
				"Transcript cr; print: b; endEntry."
				b selectors "asSortedCollection" do:
					[:s|
					[b recompile: s from: b]
						on: Error
						do: [:ex|
							Transcript
								cr; nextPutAll: 'COMPILATION ERROR: ';
								print: b; nextPutAll: '>>'; nextPutAll: s; flush.
							compilationErrors add: (MethodReference class: b selector: s)]]]]].
(Smalltalk respondsTo: #allTraits) ifTrue:
	['Recompiling Traits'
		displayProgressAt: Sensor cursorPoint
		from: 0 to: Smalltalk allTraits size
		during:
			[:bar |
			Smalltalk allTraits do:
				[:t|
				t selectors do:
					[:s|
					[t recompile: s]
						on: Error
						do: [:ex|
							Transcript
								cr; nextPutAll: 'COMPILATION ERROR: ';
								print: t; nextPutAll: '>>'; nextPutAll: s; flush.
							compilationErrors add: (MethodReference class: t selector: s)]]]]].
compilationErrors notEmpty ifTrue:
	[SystemNavigation default
		browseMessageList: compilationErrors asSortedCollection
		name: 'Compilation Errors']!